类别:数据库

日期:2021-01-25 浏览:1305 评论:0

    工作中会遇到SQL Server模拟数据生成以及数值列值(如整型、日期和时间数据类型)随机填充等等任务,这些任务中都要使用到随机数。鉴于此,本文将对SQL Server中随机数的使用简单做个总结 。
 
T-SQL 随机有关的三个函数
    
    RAND([seed] 此函数生成从0到1之间随机 float 值(详细说明查看https://technet.microsoft.com/zh-cn/library/ms177610(v=sql.90).aspx)。
 

    CHECKSUM ( * | expression [ ,...n ] ) 此函数生成按照表的某一行或一组表达式计算出来的int校验和值,CHECKSUM 用于生成哈希索引(详细说明查看https://technet.microsoft.com/zh-cn/library/ms189788(v=sql.90).aspx)。

    
    NEWID ( ) 此函数生成 uniqueidentifier 类型的唯一值(详细说明查看https://technet.microsoft.com/zh-cn/library/ms190348(v=sql.90).aspx)。
 
生成任意一个随机数值(如整数、日期和时间数据类型)
 
    如果获得任意一个随机整数值?函数RAND生成的结果是float数据类型的,显然很难满足要求,不过可以通过对函数RAND的结果继续加工(比如其结果乘以某一个值保留整数部分等等)得到要求。很显然,函数CHECKSUM生成的结果是int数据类型,很容易满足我们的结果,不过其参数如果固定(表的某一行值相同或一组表达式值相同),那么其结果也是相同的。函数NEWID可以保证结果的唯一,但是其结果是unigueidentifer数据类型的。
 
    从以上三个函数的结果值分析:函数RNAD和CHECKSUM的结果是能获得整数数值的。如果我们将函数NEWID的结果值作为函数CHECKSUM的参数,那么其每次生成的结果值都是不一样的int数据类型的数值。以下T-SQL代码如下:
SELECT CHECKSUM(NEWID()) AS CheckSumValue, CHECKSUM(NEWID()) AS CheckSumValue2;
GO
执行后的查询结果如下:

    从上面的查询结果看到组合生成的整数数值都是9位数的,平时工作中大多使用的随机整数值都是不太大的且都是自然数(0和正整数的集合),这就要求限制随机生成的整数数值。可以使用函数ABS对其结果进行处理得到任意一个自然数。这样,组合一起来的格式就是这样的:ABS(CHECKSUM(NEWID()))。为了便于使用便于使用我们通过将其封装到函数中,但是函数NEWID又不能在函数中使用,那我们就要考虑其他的方式:将函数NEWID封装在单列单行的视图中。其定义视图的T-SQL代码如下:

IF OBJECT_ID(N'dbo.vRandomGuid', 'V') IS NOT NULL
BEGIN
    DROP VIEW dbo.vRandomGuid;
END
GO

--==================================
-- 功能: 随机Guid视图
-- 说明: 具体实现阐述
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
--==================================
CREATE VIEW dbo.vRandomGuid
    --$Encode$--
AS
    SELECT RandomGuid = NEWID();
GO

--调用该视图的T-SQL代码如
SELECT TOP 1 RandomGuid
FROM dbo.vRandomGuid;
GO

执行后的查询结果如下:

82100-20151221152023827-1033869727.png82100-20151221152023827-1033869727.png
        
生成整数区间内的任意一个随机整数
    
    上面的视图定义,我们继续讲解组合函数的进一步封装。我们先讲解如何限制随机生成的数值,取模运算可以实现生成在指定数值区间内的任意一个数值,例如:获取区间[3,5]内任意一个数字,我们设为区间的最小值为@intMin:3,最大值为@intMax,则该区间的间隔值为 @intMax - @intMin + 1: 5 - 3 + 1(3),那么针对任意的整数值设为为@intValue,然后对这个间隔值先进行取模运算在加上区间最小值,最后得到的值为: @intValue % (@intMax - @intMin + 1) + @intMin。如果@intValue为8,则结果值为5;如果@intValue为9,则结果值为3;如果@intValue为10,则结果值为4……
 

    针对以上的分析我们封装的T-SQL代码如下:

IF OBJECT_ID(N'dbo.ufn_RandNum', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_RandNum;
END
GO

--==================================
-- 功能: 获取区间内的任意一个随机数值
-- 说明: 具体实现阐述
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SELECT dbo.ufn_RandNum(0, 1);
--==================================
CREATE FUNCTION dbo.ufn_RandNum
(
    @intMin INT,            -- 随机数值的最小值
    @intMax INT                -- 随机数值的最大值
) RETURNS INT
    --$Encode$--
AS
BEGIN
    SET @intMin = ISNULL(@intMin, 0);
    SET @intMax = ISNULL(@intMax, 0);

    DECLARE @guidValue AS UNIQUEIDENTIFIER;

    SELECT TOP 1 @guidValue = RandomGuid
    FROM dbo.vRandomGuid;

    RETURN ABS(CHECKSUM(@guidValue)) % (@intMax - @intMin + 1) + @intMin;
END
GO
调用以上函数的T-SQL代码如下:
 SELECT dbo.ufn_RandNum(0, 1) AS RandNum, dbo.ufn_RandNum(10, 13) AS RandNum2 from dbo.HIS_Item
执行后的查询结果如下:
82100-20151221152039968-2106350012.png82100-20151221152039968-2106350012.png
 
生成日期区间内的任意一个随机日期
 

    那么我们继续讲解 获取指定区间内的任意一个随机日期,不过我们要使用日期和时间的两个函数:DATEADD和DATEDIFF。使用DATEDIFF计算出日期区间的间隔值,同上的思路我们计算得到的一个随机整数值,然后通过DATEADD得到我们期望的一个随机日期。封装函数的T-SQL代码如下:

IF OBJECT_ID(N'dbo.ufn_RandDate', 'FN') IS NOT NULL
BEGIN
    DROP FUNCTION dbo.ufn_RandDate;
END
GO

--==================================
-- 功能: 获取日期区间内的任意一个随机日期
-- 说明: 具体实现阐述
-- 作者: XXX
-- 创建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改内容描述
-- 调用: SELECT @dtmRand = dbo.ufn_RandDate('2007-02-01', '2007-03-01');
--==================================
CREATE FUNCTION dbo.ufn_RandDate
(
    @dtmMin DATETIME,    -- 随机日期的最小值
    @dtmMax DATETIME    -- 随机日期的最大值
) RETURNS DATETIME
    --$Encode$--
AS
BEGIN
    SET @dtmMin = ISNULL(@dtmMin, '2000-01-01');
    SET @dtmMax = ISNULL(@dtmMax, '2000-01-01');
    DECLARE @guidVue AS UNIQUEIDENTIFIER;

    SELECT TOP 1 @guidVue = RandomGuid
    FROM dbo.vRandomGuid;

    -- 可以将HOUR换为DAYS
    RETURN DATEADD(HOUR, (ABS(CHECKSUM(@guidVue)) % (1 + DATEDIFF(HOUR, @dtmMax, @dtmMin))), @dtmMin);
END
GO

调用以上函数的T-SQL代码如下:

SELECT dbo.ufn_RandDate('2015-12-01', '2015-12-21') AS RandDate, dbo.ufn_RandDate('2016-12-01', '2016-12-21') AS RandDate2;
GO

执行后的查询结果如下:

82100-20151221152053390-1627834123 (1).png

 
区间随机数获取的扩展思考
    
    无论是获取数值区间内的随机数值,还是日期区间内的随机日期,我们都使用了视图vRandomGuid。如果有一个连续的数值序列,我们通过查询这个数值序列,结合我们的区间数值和随机排序,也可以实现以上的效果。
    假设该数值序列为SeqDataTable(Num INT),数值区间[@intMin,@intMax],那么该数值区间任意一个随机数值的T-SQL代码如下:
1 SELECT TOP 1 Num
2 FROM dbo.SeqDataTable
3 WHERE Num BETWEEN @intMin AND @intMax
4 ORDER BY NEWID() ASC;
5 GO

 

    当然也可以利用以上的数字序列SeqDataTable(Num INT),日期区间[@dtmMin,@dtmMax],那个该数字区间任意一个随机日期的T-SQL代码如下:

 

1 SELECT TOP 1 DATEADD(DAY, Num, @dtmMin)
2 FROM dbo.SeqDataTable
3 WHERE Num BETWEEN 0 AND DATEDIFF(DAY, @dtmMin, @dtmMax)
4 ORDER BY NEWID() ASC;
5 GO

 注意:以上代码无法执行成功的,也算是伪代码的。 

    以后会针对数字序列有专门的详细讲解,这儿暂时作为一个扩展思考吧。
 
补充数字辅助表

  获取指定范围的任意一个数字的T-SQL代码如下:

SELECT TOP 1 Num
FROM dbo.ufn_GetNums(@bintMin, @bintMax)
ORDER BY NEWID() ASC;
GO

SELECT TOP 1 Num
FROM dbo.ufn_GetNums(11, 15)
ORDER BY NEWID() ASC;
GO

获取指定范围的任意一个日期的T-SQL代码如下:

SELECT TOP 1 DATEADD(DAY, Num, @dtmMin)
FROM dbo.ufn_GetNums(0, DATEDIFF(DAY, @dtmMax, @dtmMin))
ORDER BY NEWID() ASC;
GO

SELECT TOP 1 DATEADD(DAY, Num, '2015-12-01')
FROM dbo.ufn_GetNums(0, DATEDIFF(DAY, '2015-12-01', '2015-12-05'))
ORDER BY NEWID() ASC;
GO

以上代码中的表函数ufn_GetNums可以参看这篇博文SQL Server数字辅助表的实现


本文标题:SQL Server中的RAND函数的介绍和区间随机数值函数的实现
本文链接:https://vtzw.com/post/553.html
作者授权:除特别说明外,本文由 零一 原创编译并授权 零一的世界 刊载发布。
版权声明:本文不使用任何协议授权,您可以任何形式自由转载或使用。
 您阅读本篇文章共花了: 

 可能感兴趣的文章

评论区

发表评论 / 取消回复

必填

选填

选填

◎欢迎讨论,请在这里发表您的看法及观点。

最新留言